Modular Cube

will_57 · Wed Dec 02, 2020 5:50 am

There is so much to say about this puzzle that I've broken this post into sections.

Introduction
In October 2016, Bram observed the following:

Bram wrote:Notably no puzzle has ever been found [...] where more than one type of piece have an unusual group property.

With the release of the Modular Cube, the statement above is decidedly false. This is a puzzle wherein almost all pieces have unusual group-theoretic properties.

VIDEO

Background
I started searching for group theoretically interesting puzzles in December 2016. I successfully found a planar circle puzzle with 4 different interesting groups. It consisted of a circle of order 2 and a circle of order 3. I noticed that many of the interesting groups on this planar puzzle could be realized nicely in 3 dimensions. Specifically, using the geometry of a cube, one can place the order 3 turn at a corner and the order 2 turn at a face. Unfortunately, I realized that a complete realization of the planar puzzle is impossible using this geometry. In particular, such a puzzle cannot contain both the Ree(3) and PSL(3,2) orbits: these two piece types occur in the same locations, but at different cut depths. This is when I had the idea to put holes in the PSL(3,2) pieces to expose a deeper-cut layer of Ree(3) pieces below, giving what you see here.

Design
The corner cut is deep cut and behaves exactly as expected, turning in 120 degree increments. The face cut turns in 180 degree increments only. Thus, the symmetry of this puzzle is actually tetrahedral: many pieces that look the same on the outside are chiral, or are mechanically distinct. Externally, the face cut goes through 1/3 of the puzzle, but internally it goes through 2/3 of the puzzle. This is quite unusual: whereas most puzzles based on a shell mechanism have shallower cuts on the inside and deeper cuts on the outside, this puzzle is the opposite. I used this fact to create a simpler mechanism. The deeper shells are not stable on their own, but are held in by the shallower shells above them:

The core of this puzzle is also unusual. It consists of a rotating dome screwed into the base. The two corners that act as centers of rotation are screwed into the dome:

The three other corners are attached to the core with grooves:

: Modular Cube Screenshot 3.PNG (95.15 KiB) Viewed 1757 times

The first prototype of this puzzle lacked these grooves and was incredibly unstable. Now, this is one of the most mechanically robust puzzles I have ever built. It feels especially solid in HP's new Jet Fusion, weighing 82 grams.

As with all of my recent designs, I'm making this one available to the public. It is available for download from here.

Unusual groups
The following groups contained in this puzzle are of particular interest from the perspective of solving:

There are two orbits of corner pieces: one with 2 pieces, and one with 3 pieces. However, they solve simultaneously, and are both groups of order 18.
The triangle-shaped center pieces fall into two orbits of 8 pieces each. Both orbits are isomorphic to the group PGL(2,7), but they are actually asymmetric. Indeed, one of the orbits can be solved in fewer moves than the other. These pieces and the corner pieces had the same properties on Solver's Chop; this is because Solver's Chop can be viewed as a strict subset of the Modular Cube.
The pieces with holes in them form two orbits of 7 pieces each. Both orbits are isomorphic to the group PSL(3,2), which is also the same group as GL(3,2), SL(3,2), PGL(3,2), and PSL(2,7). These two orbits have the strange property that they solve simultaneously despite being mirrors of one another.
The pieces below the PSL(3,2) pieces fall into two orbits of 9 pieces each. Both orbits are isomorphic to the group Ree(3), which is also isomorphic to PΓL(2,8). An isomorphic group was identified previously on the Trapentrix.
The orbit of 9 edge pieces is isomorphic to the group PSL(2,Z9) (not to be confused with PSL(2,9)).

It remains unclear whether having many weird groups like these makes a puzzle harder or easier to solve. On the one hand, certain moves simply don't exist: many of these groups lack a 3-cycle. But on the other hand, these groups have many fewer reachable permutations than the corresponding symmetric groups on the same number of pieces. As a result, solving these groups often requires solving fewer pieces. Undoubtedly, however, a puzzle like this provides a unique solving experience compared to most other twisty puzzles. I look forward to hearing what solvers think.

For convenience, I've also provided generators for the puzzle so you can follow along in GAP:

Code: Select all

faceTurn := 
(1,79)(2,68)(3,69)(4,58)(5,67)(6,70)(10,78)(12,80)(13,46)(15,71)(16,49)(17,65)(19,55)(20,66)(21,76)(22,72)(23,52)(24,75)(25,28)(26,64)(30,73)(31,44)(32,40)(34,38)(35,61)(37,62)(53,74)(57,77);
cornerTurn := (1,2,3)(4,5,6)(7,8,9)(10,11,12)(13,14,15)(16,17,18)(19,20,21)(22,23,24)(25,26,27)(28,29,30)(31,32,33)(34,35,36)(37,38,39)(40,41,42)(43,44,45)(46,47,48)(49,50,51)(52,53,54)(55,56,57)(58,59,60)(61,62,63);
cube := Group(faceTurn, cornerTurn);

The modular group
The name of this puzzle comes from its connections to the modular group, the group PSL(2,Z). In words, the modular group is the infinite group of 2x2 integer matrices with determinant 1, modulo the equivalence relation [[a,b],[c,d]] ~ [[-a,-b],[-c,-d]]. This group is well-studied through the theory of modular forms for applications to complex analysis and number theory. Here, I will just focus on the group-theoretic properties. The modular group has a canonical set of generators: S = +-[[0,-1],[1,0]] and T = +-[[1,1],[0,1]]. These elements satisfy the relations S^2 = (ST)^3 = 1. Surprisingly, these relations are also a complete description of the group, but this is harder to prove. In other words, the modular group is equivalently described by the presentation <a,b | a^2 = b^3 = 1>. This essentially means that the modular group is the largest group generated by an element of order 2 and an element of order 3; it is the free product C_2 * C_3. This also means that every group generated by elements a and b of order 2 and 3, respectively, can be expressed as a quotient of the modular group by adding additional relations. Because the Modular Cube is generated by a face turn of order 2 and a corner turn of order 3, the groups contained within are no exception.

A surprising connection
While putting this post together, I noticed that at least one interesting group in this puzzle already exists naturally as a quotient of the modular group. For example, one can obtain PSL(2,7) from the modular group by reducing the matrix entries mod 7, giving rise to a surjective homomorphism from the modular group to PSL(2,7). Alternatively, one can view PSL(2,7) as the quotient of the modular group by the congruence subgroup Γ(7) of matrices +-[[a,b],[c,d]] satisfying a ≡ d ≡ 1 (mod 7) and c ≡ d ≡ 0 (mod 7). Upon realizing this, I had to ask: do any groups in the Modular Cube correspond to "natural" quotients from the modular group? It is not at all obvious that this should be true. Indeed, two isomorphic quotients of a group need not arise out of quotients by the same subgroup. For example, the two PGL(2,7) orbits do not solve simultaneously; this alone implies that they arise out of the modular group by quotients of different subgroups.

We can answer this question this as follows: using GAP, construct a presentation for each group using the generators of order 2 and 3. This yields a set of "words" that reduce to the identity on the "symbols" F1 and F2, which represent generators of order 2 and 3, respectively. Take each relation from the presentation, and substitute in the generators for the corresponding matrices in the modular group (F1 -> s, F2 -> s*t). This yields a set of matrices whose normal closure generates the kernel of the homomorphism from the modular group to the puzzle group. We can check by hand if these matrices lie in the expected "natural" subgroup.

Here is the relevant GAP code:

Code: Select all

# Standard generators for SL(2,Z): s has order 4, st has order 6
# After taking the quotient by +-[[1,0],[0,1]], this yields the modular group PSL(2,Z)
# Unfortunately, GAP doesn't allow us to construct this quotient explicitly
# So, we'll have to just account for this when we look at the matrices below
s := [[0,-1],[1,0]];
t := [[1,1],[0,1]];
modular_gens := [s, s*t];

# Isolate the groups acting on each orbit
orbits := Orbits(cube);
actions := List(orbits, o -> Action(cube, o));
for a in actions do
  # Print the group
  Print(a,":\n");
  Print(StructureDescription(a)," of size ",Size(a),"\n");
  # Construct an isomorphism to a finitely presented group using the same generators
  iso := IsomorphismFpGroupByGenerators(a, GeneratorsOfGroup(a));
  # The image of the isomorphism
  fp := Image(iso);
  # Generators of the finitely presented group
  fp_gens := FreeGeneratorsOfFpGroup(fp);
  # Relators of the finitely presented group
  # There are words in the generators (fp_gens) that reduce to the identity
  rels := RelatorsOfFpGroup(fp);
  for rel in rels do
    # Print the relator
    Print("Relator: ", rel, "\n");
    # Map each relator to a matrix in SL(2,Z) by substitution
    # Crucially, fp_gens and modular_gens are in the same order:
    # The first element in each list is the generator of order 2
    # The second element in each list is the generator of order 3
    Display(MappedWord(rel, fp_gens, modular_gens));
  od;
  Print("\n");
od;

Let's go through some examples from the output of the code above. I'll start with one of the orbits of pieces with holes through them:

Code: Select all

Group( [ (1,2)(3,5), (1,3,6)(2,4,7) ] ):
PSL(3,2) of size 168
Relator: F1^2
[ [  -1,   0 ],
  [   0,  -1 ] ]
Relator: F2^3
[ [  -1,   0 ],
  [   0,  -1 ] ]
Relator: (F1*F2^-1)^7
[ [  1,  0 ],
  [  7,  1 ] ]
Relator: (F2*F1*F2^-1*F1)^4
[ [   13,  -21 ],
  [  -21,   34 ] ]
Relator: (F2*(F1*F2^-1)^2*F1)^4
[ [    41,  -112 ],
  [   -56,   153 ] ]

Recall that PSL(3,2) is isomorphic to PSL(2,7). Notice that if we reduce mod 7, all of the matrices are congruent to +-[[1,0],[0,1]] mod 7. So, the normal closure of these matrices is contained in the congruence subgroup Γ(7), because Γ(7) is a normal subgroup of the modular group. This normal closure is the kernel of the homomorphism from the modular group into this particular representation of PSL(2,7). On the other hand, we know that the quotient of the modular group by Γ(7) has size 168. If the normal closure were a proper subgroup of Γ(7), then the quotient by this subgroup would have size strictly greater than 168. But this is not the case: we know that this orbit is isomorphic to PSL(2,7) of size 168. So, we conclude that the normal closure is Γ(7), exactly as predicted! This also offers one explanation for why both orbits of this type solve simultaneously: they arise identically as quotients of the modular group.

Let's do the same analysis for one of the other groups. This is the group acting on the orbit of 9 edge pieces:

Code: Select all

Group( [ (1,2)(3,5), (1,3,6)(2,4,7)(5,8,9) ] ):
((C3 x ((C3 x C3) : C2)) : C2) : C3 of size 324
Relator: F1^2
[ [  -1,   0 ],
  [   0,  -1 ] ]
Relator: F2^3
[ [  -1,   0 ],
  [   0,  -1 ] ]
Relator: (F1*F2)^9
[ [  -1,  -9 ],
  [   0,  -1 ] ]
Relator: (F1*F2*(F1*F2^-1)^2)^2*(F1*F2)^2*F1*F2^-1*F1*F2
[ [  -37,  -63 ],
  [  -27,  -46 ] ]
Relator: (F1*F2*F1*F2^-1)^6
[ [  233,  144 ],
  [  144,   89 ] ]
Relator: ((F2^-1*F1)^2*F2*F1*F2*(F1*F2*F1*F2^-1)^2*F1)^2
[ [   431,  -675 ],
  [  -189,   296 ] ]

GAP doesn't print a nice structure description for this group, but I previously showed that this group is isomorphic go PSL(2,Z9). And indeed, one can also verify that all of the matrices above are congruent to +-[[1,0],[0,1]] mod 9. So, by the same argument as above, the normal closure of these matrices is the congruence subgroup Γ(9).

Let's look at one more group, this time the group acting on orbit of 5 edge pieces:

Code: Select all

Group( [ (1,2)(4,5), (1,3,4) ] ):
A5 of size 60
Relator: F1^2
[ [  -1,   0 ],
  [   0,  -1 ] ]
Relator: F2^3
[ [  -1,   0 ],
  [   0,  -1 ] ]
Relator: (F1*F2^-1)^5
[ [  1,  0 ],
  [  5,  1 ] ]

We don't usually consider the alternating group A5 interesting, particularly when it acts on just 5 points. However, A5 is isomorphic to PSL(2,5). And as before, one can verify that the matrices above are all congruent to +-[[1,0],[0,1]] mod 5, implying that the normal closure they generate is the congruence subgroup Γ(5).

I later realized that this might be less of a coincidence than I thought. It turns out that there is only one way to generate each of these groups (up to isomorphism) by an element of order 2 and an element of order 3. This is easily verified in GAP by looking for a pair of elements of order 2 and 3 that generate a group not isomorphic to the original one when mapping corresponding generators. For example:

Code: Select all

gap> g := Group((1,2)(3,5), (1,3,6)(2,4,7));
Group([ (1,2)(3,5), (1,3,6)(2,4,7) ])
gap> ForAny(g, g2 -> Order(g2) = 2 and
> ForAny(g, g3 -> Order(g3) = 3 and
> Size(Group(g2, g3)) = Size(g) and
> GroupHomomorphismByImages(g, Group(g2, g3)) = fail));
false

Conclusion
This is one of the most mathematically strange twisty puzzles ever created. It has surprising connections to well-studied mathematical objects, but it remains unclear if the oddities seen in this puzzle are "just" a bunch of coincidences, or if there is a distinct pattern here. Some questions remain open:

Is there a nice explanation for why the two PSL(2,7) orbits solve simultaneously (that doesn't involve a connection to the modular group)?
Is there a nice connection between the modular group and the other groups on this puzzle?
The three piece types discussed in the last section share the property that the face turn moves exactly 4 pieces in each orbit. Does this explain any of the patterns seen here?